The "problem" with triangles is that you can "see" them only from one side - so I tend to define the triangle twice.
One clockwise and the other one counter clockwise.
Once that is done they open up a lot of new structures - here are 5 of them
All basically generated in the same way - just with positive or negative rotation.
set background #777

set colorpool list:#E13800,#DF811D,#92C6C2,#E1D0B2

rule regtri2{
{s 1 } triangle[-1,0,1;0,1,0;1,0,1]
{s 1 } triangle[1,0,1;0,1,0;-1,0,1]
}

rule wtribox1{
4 * { rz 90 x  1} 4 * {ry -90 x 1} 1 * { ry -90 x 1 color random }regtri2
}
rule wtribox2{
4 * { rz -90 x  1} 3 * {ry 90 x 1} 1 * { ry 90 x 1 color random }regtri2
}
rule wtribox3{
4 * { rz 90 x  1} 3 * {ry 90 x 1} 1 * { ry 90 x 1 color random }regtri2
}
rule wtribox4{
4 * { rz -90 x  1} 3 * {ry -90 x 1} 1 * { ry -90 x 1 color random }regtri2
}
rule wtribox5{
4 * { rz -90 x  1} 4 * {ry 90 x 1} 1 * { ry -90 x 1 color random }regtri2
}

3 * {y -4 x 5 rz 30}wtribox5
1 * { y 4} 3 * {y -4 x 5 rz 30}wtribox4
1 * { y 7} 3 * {y -4 x 5 rz 30}wtribox3
1 * { y 12} 3 * {y -4 x 5 rz 30}wtribox2
1 * { y 15} 3 * {y -4 x 5 rz 30}wtribox1

That will create the image below.

Linkback: https://fractalforums.org/structuresynth-and-browsersynth/79/triangles-often-overlooked-primitive-in-structuresynth/3929/

Triangles can also be used for Rubik's snake like structures
snake

rule snake{
snakepart
{ry 90 rz 90 x -10}snake
}
rule snake w 0.1{
snakepart
{rz 90 x -10}snake
}
rule snake w 0.2{
snakepart
{rz 180 x 0}snake
}


rule snakepart{
{color red}snakepart1
{rz -45 s 0.02 9 9 rz -45 color white}box
}

rule snakepart{
{color white}snakepart1
{rz -45 s 0.02 9 9 rz -45 color red}box
}
rule snakepart{
{color black}snakepart1
{rz -45 s 0.02 9 9 rz -45 color red}box
}

rule snakepart1{
{s 10}tri
{s 10 z 1}tri
{y -5 s 10 0.01 10}box
{x 5 s 0.01 10 10}box
{rz -45 s 0.01 10 10 rz -45}box
}

rule tri{
triangle[0,0,0; 1,0,0;1,1,0]
triangle[0,0,0; 1,1,0;1,0,0]
}