You can use the parameter space images to pick 2D Julia sets, there is one for every (a,b) point in 4D space.

If you pick a pointwith both critical orbits escaping, Julia set is totally disconnected, of neither escape it's connected, of one escapes and the other not it's disconnected but with connected parts (blobs).

Here's one and the UF code I use. I save DE in final z which I use for coloring.

`CubicM {`

init:

c = #pixel

float theta = real(@angles)*2*#pi

float phi = imag(@angles)*2*#pi

float psi = 0

wcmult = exp(1i*(theta + psi)) * sin(phi)

zcmult = exp(1i*(psi)) * cos(phi)

cz = @centerz

cw = @centerw

if(@corbit == 0)

z = 0

else

z = -2*(wcmult*c+cw)/3

endif

dz = 0

acoeff = (wcmult*c+cw)

bcoeff = (zcmult*c+cz)

bool hasEscaped = false

loop:

dz = dz*(3*z^2 + acoeff*z*2)+ wcmult*z^2 + zcmult

z = z^3 + acoeff*z^2 + bcoeff

if |z| > @bailout

hasEscaped = true

z = #magn * z*log(cabs(z))/dz

z = z^@dePower

endif

bailout:

!hasEscaped

default:

title = "CubicM"

center = (0, 0)

float param bailout

caption = "bailout"

default = 1e10

endparam

complex param centerw

caption = "center w"

default = 0

endparam

complex param centerz

caption = "center z"

default = 0

endparam

complex param angles

caption = "thetaPhi"

default = 0

endparam

float param dePower

caption = ""

default = 1

endparam

int param corbit

caption = "0 or 1"

default = 0

endparam

switch:

type = "CubicJ"

centerw = centerw

centerz = centerz

angles = angles

dePower = dePower

seed = #pixel

bailout = bailout

}

CubicJ {

init:

c = @seed

float theta = real(@angles)*2*#pi

float phi = imag(@angles)*2*#pi

;float psi = @rot*2*#pi

float psi = 0

wcmult = exp(1i*(theta + psi)) * sin(phi)

zcmult = exp(1i*(psi)) * cos(phi)

cz = @centerz

cw = @centerw

dz = 1

acoeff = (wcmult*c+cw)

bcoeff = (zcmult*c+cz)

z = #pixel

bool hasEscaped = false

loop:

dz = dz*(3*z^2 + acoeff*z*2)+ wcmult*z^2; + zcmult

z = z^3 + acoeff*z^2 + bcoeff

if |z| > @bailout

hasEscaped = true

z = #magn * z*log(cabs(z))/dz

z = z^@dePower

endif

bailout:

!hasEscaped

default:

title = "CubicJ"

center = (0, 0)

float param bailout

caption = "bailout"

default = 1e10

endparam

complex param centerw

caption = "center w"

default = 0

endparam

complex param centerz

caption = "center z"

default = 0

endparam

complex param angles

caption = "thetaPhi"

default = 0

endparam

float param dePower

caption = ""

default = 1

endparam

switch:

type = "CubicM"

centerw = centerw

centerz = centerz

angles = angles

dePower = dePower

bailout = bailout

}